From effde76eaf363b0cc464f52c1b5eb3bf99a136fe Mon Sep 17 00:00:00 2001
From: Thomas FORGIONE <thomas.forgione@gmail.com>
Date: Thu, 8 Sep 2016 11:25:10 +0200
Subject: [PATCH] Added myjump

---
 zsh/oh-my-zsh/plugins/myjump.plugin.zsh | 61 +++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 zsh/oh-my-zsh/plugins/myjump.plugin.zsh

diff --git a/zsh/oh-my-zsh/plugins/myjump.plugin.zsh b/zsh/oh-my-zsh/plugins/myjump.plugin.zsh
new file mode 100644
index 0000000..af8c78d
--- /dev/null
+++ b/zsh/oh-my-zsh/plugins/myjump.plugin.zsh
@@ -0,0 +1,61 @@
+# Easily jump around the file system by manually adding marks
+# marks are stored as symbolic links in the directory $MARKPATH (default $HOME/.marks)
+#
+# jump FOO: jump to a mark named FOO
+# mark FOO: create a mark named FOO
+# unmark FOO: delete a mark
+# marks: lists all marks
+#
+export MARKPATH=$HOME/.marks
+
+jump() {
+    if [ "$2" == "-p" ]; then
+        echo "$MARKPATH/$1"
+    else
+        cd -P "$MARKPATH/$1" 2>/dev/null || echo "No such mark: $1"
+    fi
+}
+
+mark() {
+	if [[ ( $# == 0 ) || ( "$1" == "." ) ]]; then
+		MARK=$(basename "$PWD")
+	else
+		MARK="$1"
+	fi
+	if read -q \?"Mark $PWD as ${MARK}? (y/n) "; then
+		mkdir -p "$MARKPATH"; ln -s "$PWD" "$MARKPATH/$MARK"
+	fi
+}
+
+unmark() {
+	rm -i "$MARKPATH/$1"
+}
+
+marks() {
+	for link in $MARKPATH/*(@); do
+		local markname="$fg[cyan]${link:t}$reset_color"
+		local markpath="$fg[blue]$(readlink $link)$reset_color"
+		printf "%s\t" $markname
+		printf "-> %s \t\n" $markpath
+	done
+}
+
+_completemarks() {
+	if [[ $(ls "${MARKPATH}" | wc -l) -gt 1 ]]; then
+		reply=($(ls $MARKPATH/**/*(-) | grep : | sed -E 's/(.*)\/([_a-zA-Z0-9\.\-]*):$/\2/g'))
+	else
+		if readlink -e "${MARKPATH}"/* &>/dev/null; then
+			reply=($(ls "${MARKPATH}"))
+		fi
+	fi
+}
+compctl -K _completemarks jump
+compctl -K _completemarks unmark
+
+_mark_expansion() {
+	setopt extendedglob
+	autoload -U modify-current-argument
+	modify-current-argument '$(readlink "$MARKPATH/$ARG")'
+}
+zle -N _mark_expansion
+bindkey "^g" _mark_expansion